域名将于6月份到期,并且不再续费,届时网站将无法访问。
6月份之前如果服务器到期将提前关闭网站,请改访问模组网社区

Oblivion硬盘版打包脚本(NSIS)

放出早期自己打包Oblivion硬盘版的NSIS脚本,稍微调整一下其实就可以做Skyrim的硬盘版了。

编译需求:NSIS64,这个是必须的,不然NSIS打包没法超过2G、没法多文件

转换成Skyrim硬盘版需要做的调整:

  • (尚不清楚Steam是否需要这一步)找出安装Skyrim后在注册表中产生的卸载编号,用来替换{35CB6715-41F8-4F99-8881-6FC75BF054B0};
  • 找出Skyrim保存在注册表的安装路径,用来替换HKLM\Software\Bethesda Softworks\Oblivion……这个简单,就是HKLM\Software\Bethesda Softworks\Skyrim了;
  • 把里面的DirectX9.0c替换为DirectX10……装了Razor的那个版本里面提到的是10;
  • 除了安装DirectX外,还另外增加.Net或者C++的检测与安装……忘了是哪个,这个也是Razor原版安装的配件;
  • 收集下官方指南、使用手册,把他整合进去;
  • 官方编辑器CK……如果没有原版exe安装程序就放着,不要打包中文版,skse会认CRC,到时一堆人为了让skse能启动CK又必须换回原版。

最后,建议用WinISO或者其他相关工具将Out目录的文件全部压缩成ISO

效果的话,可以查看Oblivion硬盘版里面的预览,安装前会先检测电脑内是否有旧版游戏存在(存在的话要求先卸载干净)、判断是否装进PF目录(会警告,但不会强制调整)

Show the Content

; Oblivion NSIS Installer Script

;-------------------------------- Includes:
    !include "MUI2.nsh"
    !include "LogicLib.nsh"
    !include "nsDialogs.nsh"
	!include "WordFunc.nsh"
	!include "StrFunc.nsh"
    ; declare used functions
    ${StrLoc}

;-------------------------------- Basic Installer Info:
	Name "《上古卷轴4:湮没》五周年纪念版"
	OutFile "OutFile\Setup.exe"

	;Request application privileges for Windows Vista/7
	RequestExecutionLevel admin

	; This causes an "are you sure?" message to be displayed if you try to quit the installer or uninstaller.
	!define MUI_ABORTWARNING
	!define MUI_UNABORTWARNING

	SetCompress auto
	;SetCompressor /SOLID lzma
	;Nsis64 doesn't support lzma

	filesize 2000 ; Sets the max single file size in megabytes, 0 means no limit.
	; SetDataFile force ; it can be off/auto/force, default is auto.
	; if SetDataFile set to auto,and FileSize set to be 0, it means once the total length reaches 4GB, it will use data file ,and the data file is single
	; if SetDataFile set to auto,and FileSize set to be none-zero, it means once the total length reaches FileSize, it will use data file, and the data file is stored per FileSize.

;-------------------------------- Variables:
	Var Dialog
	Var Label
	Var Empty
	Var True

	Var Path
	Var Uninstalled
	Var Installed
		; 1		Detected {35CB6715-41F8-4F99-8881-6FC75BF054B0}
		; 2		Detected Software\Bethesda Softworks\Oblivion
		; 3		Detected Oblivion.ini

;-------------------------------- Page List:
	!define MUI_WELCOMEFINISHPAGE_BITMAP "images\installbackground.bmp"
	!define MUI_ICON "OutFile\Oblivion.ico"
	!define MUI_UNICON "OutFile\Oblivion.ico"
	BrandingText "《上古卷轴4:湮没》五周年纪念版 硬盘版"
	!insertmacro MUI_PAGE_WELCOME
	Page custom PAGE_CHECK_INSTALLATION

	!insertmacro MUI_PAGE_LICENSE "Game\Readme.txt"
	!insertmacro MUI_PAGE_DIRECTORY
	Page custom PAGE_CHECK_LOCATIONS PAGE_CHECK_LOCATIONS_Leave
	!insertmacro MUI_PAGE_COMPONENTS
	!insertmacro MUI_PAGE_INSTFILES
	!define MUI_FINISHPAGE_NOAUTOCLOSE
	!define MUI_FINISHPAGE_SHOWREADME "http://tesfans.org/oblivion-5th-anniversary-edition/"
	!define MUI_FINISHPAGE_SHOWREADME_TEXT "联网说明/检查更新"
	!insertmacro MUI_PAGE_FINISH

	!define MUI_UNWELCOMEFINISHPAGE_BITMAP "images\uninstallbackground.bmp"
	!insertmacro MUI_UNPAGE_WELCOME
	!insertmacro MUI_UNPAGE_COMPONENTS
	!insertmacro MUI_UNPAGE_INSTFILES

	!insertmacro MUI_LANGUAGE "SimpChinese"

;--------------------------------
;Initialisations
	Function .onInit
		StrCpy $INSTDIR "$PROGRAMFILES\Bethesda Softworks\Oblivion"
		splash::show 5000 "Setup"
		Pop $0
	FunctionEnd

	Function un.onInit
		ReadRegStr $INSTDIR	HKLM "Software\Bethesda Softworks\Oblivion" "Installed Path"
	FunctionEnd

;-------------------------------- Check Locations Page
	Function PAGE_CHECK_INSTALLATION
		!insertmacro MUI_HEADER_TEXT $(PAGE_CHECK_INSTALLATION_TITLE) $(PAGE_CHECK_INSTALLATION_SUBTITLE)
		StrCpy $Empty ""
		StrCpy $True "True"
		ReadRegStr $Uninstalled  HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\{35CB6715-41F8-4F99-8881-6FC75BF054B0}" "DisplayVersion"
		${If} $Uninstalled == $Empty ;Try 64 bit path.
			ReadRegStr $Uninstalled  HKLM "SOFTWARE\Wow6432Node\Microsoft\Windows\CurrentVersion\Uninstall\{35CB6715-41F8-4F99-8881-6FC75BF054B0}" "DisplayVersion"
		${EndIf}
		ReadRegStr $Path	HKLM "Software\Bethesda Softworks\Oblivion" "Installed Path"
		${If} $Path == $Empty ;Try 64 bit path.
			ReadRegStr $Path HKLM "Software\Wow6432Node\Bethesda Softworks\Oblivion" "Installed Path"
		${EndIf}

		${If} $Uninstalled != $Empty
			StrCpy $Installed  "1"
		${EndIf}

		${If} $Path != $Empty
			StrCpy $Installed  "2"
		${EndIf}

		IfFileExists "$DOCUMENTS\My Games\Oblivion\Oblivion.ini" 0 +2
			StrCpy $Installed  "3"

		${If} $Installed != $Empty
			nsDialogs::Create 1018
		Pop $Dialog
			${If} $Dialog == error
				Abort
			${EndIf}

			${NSD_CreateLabel} 0 0 100% 17u "安装出错:$\n电脑内已安装旧版本,或者安装的旧版没有完全卸载干净。"
				IntOp $0 0 + 17
			${NSD_CreateLabel} 0 $0u 100% 13u "可能的错误信息为:"
				IntOp $0 $0 + 13
			${If} $Installed == "3"
				${NSD_CreateLabel} 0 $0u 100% 20u "* 检测到$DOCUMENTS\My Games\Oblivion\Oblivion.ini,请删除再重试。"
					IntOp $0 $0 + 13
			${Endif}
			${If} $Installed == "2"
				${NSD_CreateLabel} 0 $0u 100% 50u "* 检测到残留注册表项目$\n(32位系统)HKEY_LOCAL_MACHINE\SOFTWARE\Bethesda Softworks\$\n或者$\n(64位系统)HKEY_LOCAL_MACHINE\SOFTWARE\Wow6432Node\Bethesda Softworks\$\n请正常卸载游戏后再重试。"
					IntOp $0 $0 + 13
			${Endif}
			${If} $Installed == "1"
				${NSD_CreateLabel} 0 $0u 100% 80u "* 检测到残留注册表项目$\n(32位系统)HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion$\n\Uninstall\{35CB6715-41F8-4F99-8881-6FC75BF054B0}$\n或者$\n(64位系统)HKEY_LOCAL_MACHINE\SOFTWARE\Wow6432Node\Microsoft\Windows$\n\CurrentVersion\Uninstall\{35CB6715-41F8-4F99-8881-6FC75BF054B0}$\n请正常卸载游戏后再重试。"
			${Endif}

			GetDlgItem $0 $HWNDPARENT 1 ; Hide Next
			ShowWindow $0 ${SW_HIDE}
			GetDlgItem $0 $HWNDPARENT 3	; Hide Back
			ShowWindow $0 ${SW_HIDE}

			nsDialogs::Show
		${EndIf}

	FunctionEnd

    Function PAGE_CHECK_LOCATIONS
        !insertmacro MUI_HEADER_TEXT $(PAGE_CHECK_LOCATIONS_TITLE) $(PAGE_CHECK_LOCATIONS_SUBTITLE)

        ; test for installation in program files
        StrCpy $1 $Empty
        ${StrLoc} $0 $INSTDIR "$PROGRAMFILES\" ">"
        ${If} "0" == $0
            StrCpy $1 $True
        ${Endif}

        ${If} $1 == $Empty
            ; nothing installed in program files: skip this page
            Abort
        ${Endif}

        nsDialogs::Create 1018
        Pop $Dialog
        ${If} $Dialog == error
            Abort
        ${EndIf}

        ${NSD_CreateLabel} 0 0 100% 24u "检测到你要将游戏安装到Program Files目录。"
        Pop $Label
        SetCtlColors $Label "FF0000" "transparent"

        ${NSD_CreateLabel} 0 24 100% 128u "这是Vista与Win7的普遍问题了,如果你把游戏安装到Program Files目录,游戏以及后面安装的程序会受到UAC的影响而无法正常工作,产生无法预计的错误,甚至可能无法启动。$\n$\n我们强烈建立你移动到其他路径,比如C:\Games\Oblivion。"
        Pop $Label

        nsDialogs::Show
    FunctionEnd

    Function PAGE_CHECK_LOCATIONS_Leave
    FunctionEnd

;-------------------------------- COMPONENTS
	InstType "完整安装"
	InstType "最简安装"

	Section "游戏本体" Desc_Main
		SectionIn 1 2 RO
		SetOutPath "$INSTDIR"
		File "Game\atimgpud.dll"
		File "Game\Bethesda.TXT"
		File "Game\binkw32.dll"
		File "Game\LauncherMusic.wav"
		File "Game\Oblivion.exe"
		File "Game\Oblivion_default.ini"
		File "Game\OblivionLauncher.exe"
		File "Game\Readme.txt"
		SetOutPath "$INSTDIR\Data\Music\Battle"
		File "Game\Data\Music\Battle\battle_01.mp3"
		File "Game\Data\Music\Battle\battle_02.mp3"
		File "Game\Data\Music\Battle\battle_03.mp3"
		File "Game\Data\Music\Battle\battle_04.mp3"
		File "Game\Data\Music\Battle\battle_05.mp3"
		File "Game\Data\Music\Battle\battle_06.mp3"
		File "Game\Data\Music\Battle\battle_07.mp3"
		File "Game\Data\Music\Battle\battle_08.mp3"
		SetOutPath "$INSTDIR\Data\Music\Dungeon"
		File "Game\Data\Music\Dungeon\Dungeon_01_v2.mp3"
		File "Game\Data\Music\Dungeon\Dungeon_02.mp3"
		File "Game\Data\Music\Dungeon\Dungeon_03.mp3"
		File "Game\Data\Music\Dungeon\Dungeon_04.mp3"
		File "Game\Data\Music\Dungeon\Dungeon_05.mp3"
		SetOutPath "$INSTDIR\Data\Music\Explore"
		File "Game\Data\Music\Explore\atmosphere_01.mp3"
		File "Game\Data\Music\Explore\atmosphere_03.mp3"
		File "Game\Data\Music\Explore\atmosphere_04.mp3"
		File "Game\Data\Music\Explore\atmosphere_06.mp3"
		File "Game\Data\Music\Explore\atmosphere_07.mp3"
		File "Game\Data\Music\Explore\atmosphere_08.mp3"
		File "Game\Data\Music\Explore\atmosphere_09.mp3"
		SetOutPath "$INSTDIR\Data\Music\Public"
		File "Game\Data\Music\Public\town_01.mp3"
		File "Game\Data\Music\Public\town_02.mp3"
		File "Game\Data\Music\Public\town_03.mp3"
		File "Game\Data\Music\Public\town_04.mp3"
		File "Game\Data\Music\Public\town_05.mp3"
		SetOutPath "$INSTDIR\Data\Music\Special"
		File "Game\Data\Music\Special\death.mp3"
		File "Game\Data\Music\Special\success.mp3"
		File "Game\Data\Music\Special\tes4title.mp3"
		SetOutPath "$INSTDIR\Data\Shaders"
		File "Game\Data\Shaders\shaderpackage001.sdp"
		File "Game\Data\Shaders\shaderpackage002.sdp"
		File "Game\Data\Shaders\shaderpackage003.sdp"
		File "Game\Data\Shaders\shaderpackage004.sdp"
		File "Game\Data\Shaders\shaderpackage005.sdp"
		File "Game\Data\Shaders\shaderpackage006.sdp"
		File "Game\Data\Shaders\shaderpackage007.sdp"
		File "Game\Data\Shaders\shaderpackage008.sdp"
		File "Game\Data\Shaders\shaderpackage009.sdp"
		File "Game\Data\Shaders\shaderpackage010.sdp"
		File "Game\Data\Shaders\shaderpackage011.sdp"
		File "Game\Data\Shaders\shaderpackage012.sdp"
		File "Game\Data\Shaders\shaderpackage013.sdp"
		File "Game\Data\Shaders\shaderpackage014.sdp"
		File "Game\Data\Shaders\shaderpackage015.sdp"
		File "Game\Data\Shaders\shaderpackage016.sdp"
		File "Game\Data\Shaders\shaderpackage017.sdp"
		File "Game\Data\Shaders\shaderpackage018.sdp"
		File "Game\Data\Shaders\shaderpackage019.sdp"
		SetOutPath "$INSTDIR\Data\Textures\Effects"
		File "Game\Data\Textures\Effects\TerrainNoise.dds"
		SetOutPath "$INSTDIR\Data\Video"
		File "Game\Data\Video\bethesda softworks HD720p.bik"
		File "Game\Data\Video\CreditsMenu.bik"
		File "Game\Data\Video\game studios.bik"
		File "Game\Data\Video\Map loop.bik"
		File "Game\Data\Video\Oblivion iv logo.bik"
		File "Game\Data\Video\Oblivion Legal.bik"
		File "Game\Data\Video\OblivionIntro.bik"
		File "Game\Data\Video\OblivionOutro.bik"
		SetOutPath "$INSTDIR\Data"
		File "Game\Data\Credits.txt"
		File "Game\Data\DLCList.txt"
		File "Game\Data\Oblivion - Meshes.bsa"
		File "Game\Data\Oblivion - Misc.bsa"
		File "Game\Data\Oblivion - Sounds.bsa"
		File "Game\Data\Oblivion - Textures - Compressed.bsa"
		File "Game\Data\Oblivion - Voices1.bsa"
		File "Game\Data\Oblivion - Voices2.bsa"
		File "Game\Data\Oblivion.esm"
		File "Game\Data\DLCShiveringIsles - Meshes.bsa"
		File "Game\Data\DLCShiveringIsles - Voices.bsa"
		File "Game\Data\DLCShiveringIsles - Sounds.bsa"
		File "Game\Data\DLCShiveringIsles - Textures.bsa"
		File "Game\Data\DLCShiveringIsles.esp"
		File "Game\Data\Knights.esp"
		File "Game\Data\Knights.bsa"
		;Store installation folder in registry key.
		WriteRegStr HKLM "SOFTWARE\Bethesda Softworks\Oblivion" "Installed Path" "$INSTDIR"
		WriteRegStr HKLM "SOFTWARE\Bethesda Softworks\Oblivion\1.2.0416" "" ""
		WriteRegStr HKLM "SOFTWARE\Bethesda Softworks\Oblivion - Shivering Isles/Knights of the Nine" "" ""
		WriteRegStr HKLM "SOFTWARE\Bethesda Softworks\Oblivion - Shivering Isles/Knights of the Nine\1.00.0000" "" ""
		;Write registry keys for Windows' uninstaller.
		WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\{35CB6715-41F8-4F99-8881-6FC75BF054B0}" "DisplayName" "Oblivion"
		WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\{35CB6715-41F8-4F99-8881-6FC75BF054B0}" "DisplayVersion" "1.2.0416"
		WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\{35CB6715-41F8-4F99-8881-6FC75BF054B0}" "InstallLocation" "$INSTDIR"
		WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\{35CB6715-41F8-4F99-8881-6FC75BF054B0}" "UninstallString" '"$PROGRAMFILES\InstallShield Installation Information\{35CB6715-41F8-4F99-8881-6FC75BF054B0}\uninstall.exe"'
		WriteRegDWORD HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\{35CB6715-41F8-4F99-8881-6FC75BF054B0}" "Language" 9
		WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\{35CB6715-41F8-4F99-8881-6FC75BF054B0}" "ProductGuid" "{35CB6715-41F8-4F99-8881-6FC75BF054B0}"
		WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\{35CB6715-41F8-4F99-8881-6FC75BF054B0}" "Publisher" "Bethesda Softworks"
		WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\{35CB6715-41F8-4F99-8881-6FC75BF054B0}" "URLInfoAbout" "http://www.Bethsoft.com"
		WriteRegDWORD HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\{35CB6715-41F8-4F99-8881-6FC75BF054B0}" "NoModify" 1
		WriteRegDWORD HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\{35CB6715-41F8-4F99-8881-6FC75BF054B0}" "NoRemove" 0
        WriteRegDWORD HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\{35CB6715-41F8-4F99-8881-6FC75BF054B0}" "NoRepair" 1
		CreateDirectory "$PROGRAMFILES\InstallShield Installation Information\{35CB6715-41F8-4F99-8881-6FC75BF054B0}"
		WriteUninstaller "$PROGRAMFILES\InstallShield Installation Information\{35CB6715-41F8-4F99-8881-6FC75BF054B0}\uninstall.exe"
	SectionEnd

	Section "DirectX 9.0c" Desc_DX
		SectionIn 1 2 RO
		SetOutPath "$INSTDIR\DXREDIST"
		File /r "Game\DXREDIST\*.*"
		ExecWait '$INSTDIR\DXREDIST\DXSETUP.exe'
		DetailPrint "完成 DirectX 9.0c 的安装"
	SectionEnd

	Section "官方指南" Desc_eBook
		SectionIn 1
		SetOutPath "$DOCUMENTS\《上古卷轴4:湮没》资料\官方指南"
		File "DOX\Guides\Elder Scrolls IV Oblivion Game of the Year Prima Official eGuide.pdf"
		File "DOX\Guides\Oblivion.GAMEGUiDE-DVX\dvx_oblivion_guide.nfo"
		File "DOX\Guides\Oblivion.GAMEGUiDE-DVX\dvx_oblivion_guide.rar"
		File "DOX\Guides\Oblivion.GAMEGUiDE-DVX\dvx_oblivion_guide.sfv"
	SectionEnd

	Section "使用手册" Desc_Manual
		SectionIn 1
		SetOutPath "$DOCUMENTS\《上古卷轴4:湮没》资料\使用手册"
		File "DOX\Manual\obliv_goty_pc_man-v2.pdf"
		SetOutPath "$DOCUMENTS\《上古卷轴4:湮没》资料\使用手册\The.Elder.Scrolls.IV.Oblivion.Collectors.Edition.Addon.Scans.High.Quality-TEDOX"
		File "DOX\Manual\The.Elder.Scrolls.IV.Oblivion.Collectors.Edition.Addon.Scans.High.Quality-TEDOX\*.*"
		SetOutPath "$DOCUMENTS\《上古卷轴4:湮没》资料\使用手册\The.Elder.Scrolls.IV.Oblivion.Manual.Disc.High.Quality-TEDOX"
		File "DOX\Manual\The.Elder.Scrolls.IV.Oblivion.Manual.Disc.High.Quality-TEDOX\*.*"
		SetOutPath "$DOCUMENTS\《上古卷轴4:湮没》资料\使用手册\The_Elder_Scrolls_IV_Oblivion_Manual_Disk_Insert_HQ-JAGDOX"
		File "DOX\Manual\The_Elder_Scrolls_IV_Oblivion_Manual_Disk_Insert_HQ-JAGDOX\*.*"
	SectionEnd

	Section "官方编辑工具" Desc_Tools
		SectionIn 1
		SetOutPath "$DOCUMENTS\《上古卷轴4:湮没》资料\编辑工具"
		File "DOX\Tools\The_Elder_Scrolls_Construction_Set_v1.2\tes_construction_set_1.2.404.exe"
		ExecWait  '"$DOCUMENTS\《上古卷轴4:湮没》资料\编辑工具\tes_construction_set_1.2.404.exe"'
		DetailPrint "完成官方编辑工具construction set 1.2.404安装"
	SectionEnd

	Section "un.游戏本体"
		Delete "$INSTDIR\atimgpud.dll"
		Delete "$INSTDIR\Bethesda.TXT"
		Delete "$INSTDIR\binkw32.dll"
		Delete "$INSTDIR\LauncherMusic.wav"
		Delete "$INSTDIR\Oblivion.exe"
		Delete "$INSTDIR\Oblivion_default.ini"
		Delete "$INSTDIR\OblivionLauncher.exe"
		Delete "$INSTDIR\Readme.txt"
		Delete "$INSTDIR\Data\Music\Battle\battle_01.mp3"
		Delete "$INSTDIR\Data\Music\Battle\battle_02.mp3"
		Delete "$INSTDIR\Data\Music\Battle\battle_03.mp3"
		Delete "$INSTDIR\Data\Music\Battle\battle_04.mp3"
		Delete "$INSTDIR\Data\Music\Battle\battle_05.mp3"
		Delete "$INSTDIR\Data\Music\Battle\battle_06.mp3"
		Delete "$INSTDIR\Data\Music\Battle\battle_07.mp3"
		Delete "$INSTDIR\Data\Music\Battle\battle_08.mp3"
		RMDir  "$INSTDIR\Data\Music\Battle"
		Delete "$INSTDIR\Data\Music\Dungeon\Dungeon_01_v2.mp3"
		Delete "$INSTDIR\Data\Music\Dungeon\Dungeon_02.mp3"
		Delete "$INSTDIR\Data\Music\Dungeon\Dungeon_03.mp3"
		Delete "$INSTDIR\Data\Music\Dungeon\Dungeon_04.mp3"
		Delete "$INSTDIR\Data\Music\Dungeon\Dungeon_05.mp3"
		RMDir  "$INSTDIR\Data\Music\Dungeon"
		Delete "$INSTDIR\Data\Music\Explore\atmosphere_01.mp3"
		Delete "$INSTDIR\Data\Music\Explore\atmosphere_03.mp3"
		Delete "$INSTDIR\Data\Music\Explore\atmosphere_04.mp3"
		Delete "$INSTDIR\Data\Music\Explore\atmosphere_06.mp3"
		Delete "$INSTDIR\Data\Music\Explore\atmosphere_07.mp3"
		Delete "$INSTDIR\Data\Music\Explore\atmosphere_08.mp3"
		Delete "$INSTDIR\Data\Music\Explore\atmosphere_09.mp3"
		RMDir  "$INSTDIR\Data\Music\Explore"
		Delete "$INSTDIR\Data\Music\Public\town_01.mp3"
		Delete "$INSTDIR\Data\Music\Public\town_02.mp3"
		Delete "$INSTDIR\Data\Music\Public\town_03.mp3"
		Delete "$INSTDIR\Data\Music\Public\town_04.mp3"
		Delete "$INSTDIR\Data\Music\Public\town_05.mp3"
		RMDir  "$INSTDIR\Data\Music\Public"
		Delete "$INSTDIR\Data\Music\Special\death.mp3"
		Delete "$INSTDIR\Data\Music\Special\success.mp3"
		Delete "$INSTDIR\Data\Music\Special\tes4title.mp3"
		RMDir  "$INSTDIR\Data\Music\Special"
		RMDir  "$INSTDIR\Data\Music"
		Delete "$INSTDIR\Data\Shaders\shaderpackage001.sdp"
		Delete "$INSTDIR\Data\Shaders\shaderpackage002.sdp"
		Delete "$INSTDIR\Data\Shaders\shaderpackage003.sdp"
		Delete "$INSTDIR\Data\Shaders\shaderpackage004.sdp"
		Delete "$INSTDIR\Data\Shaders\shaderpackage005.sdp"
		Delete "$INSTDIR\Data\Shaders\shaderpackage006.sdp"
		Delete "$INSTDIR\Data\Shaders\shaderpackage007.sdp"
		Delete "$INSTDIR\Data\Shaders\shaderpackage008.sdp"
		Delete "$INSTDIR\Data\Shaders\shaderpackage009.sdp"
		Delete "$INSTDIR\Data\Shaders\shaderpackage010.sdp"
		Delete "$INSTDIR\Data\Shaders\shaderpackage011.sdp"
		Delete "$INSTDIR\Data\Shaders\shaderpackage012.sdp"
		Delete "$INSTDIR\Data\Shaders\shaderpackage013.sdp"
		Delete "$INSTDIR\Data\Shaders\shaderpackage014.sdp"
		Delete "$INSTDIR\Data\Shaders\shaderpackage015.sdp"
		Delete "$INSTDIR\Data\Shaders\shaderpackage016.sdp"
		Delete "$INSTDIR\Data\Shaders\shaderpackage017.sdp"
		Delete "$INSTDIR\Data\Shaders\shaderpackage018.sdp"
		Delete "$INSTDIR\Data\Shaders\shaderpackage019.sdp"
		RMDir  "$INSTDIR\Data\Shaders"
		Delete "$INSTDIR\Data\Textures\Effects\TerrainNoise.dds"
		RMDir  "$INSTDIR\Data\Textures\Effects"
		RMDir  "$INSTDIR\Data\Textures"
		Delete "$INSTDIR\Data\Video\bethesda softworks HD720p.bik"
		Delete "$INSTDIR\Data\Video\CreditsMenu.bik"
		Delete "$INSTDIR\Data\Video\game studios.bik"
		Delete "$INSTDIR\Data\Video\Map loop.bik"
		Delete "$INSTDIR\Data\Video\Oblivion iv logo.bik"
		Delete "$INSTDIR\Data\Video\Oblivion Legal.bik"
		Delete "$INSTDIR\Data\Video\OblivionIntro.bik"
		Delete "$INSTDIR\Data\Video\OblivionOutro.bik"
		RMDir  "$INSTDIR\Data\Video"
		Delete "$INSTDIR\Data\Credits.txt"
		Delete "$INSTDIR\Data\DLCList.txt"
		Delete "$INSTDIR\Data\Oblivion.esm"
		Delete "$INSTDIR\Data\Oblivion - Voices1.bsa"
		Delete "$INSTDIR\Data\Oblivion - Voices2.bsa"
		Delete "$INSTDIR\Data\Oblivion - Sounds.bsa"
		Delete "$INSTDIR\Data\Oblivion - Misc.bsa"
		Delete "$INSTDIR\Data\Oblivion - Textures - Compressed.bsa"
		Delete "$INSTDIR\Data\Oblivion - Meshes.bsa"
		Delete "$INSTDIR\Data\DLCShiveringIsles - Meshes.bsa"
		Delete "$INSTDIR\Data\DLCShiveringIsles - Voices.bsa"
		Delete "$INSTDIR\Data\DLCShiveringIsles - Sounds.bsa"
		Delete "$INSTDIR\Data\DLCShiveringIsles - Textures.bsa"
		Delete "$INSTDIR\Data\DLCShiveringIsles.bsa"
		Delete "$INSTDIR\Data\DLCShiveringIsles.esp"
		Delete "$INSTDIR\Data\Knights.esp"
		Delete "$INSTDIR\Data\Knights.bsa"
		RMDir  "$INSTDIR\Data"
		RMDir  "$INSTDIR"

		;Delete registry key.
		DeleteRegKey HKLM "Software\Bethesda Softworks\Oblivion\1.2.0416"
		DeleteRegKey HKLM "Software\Bethesda Softworks\Oblivion"
		DeleteRegKey HKLM "Software\Bethesda Softworks\Oblivion - Shivering Isles/Knights of the Nine\1.00.0000"
		DeleteRegKey HKLM "Software\Bethesda Softworks\Oblivion - Shivering Isles/Knights of the Nine"
		DeleteRegKey HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\{35CB6715-41F8-4F99-8881-6FC75BF054B0}"
	SectionEnd

	Section "un.DirectX 9.0c"
		Delete "$INSTDIR\DXREDIST\*.*"
		RMDir  "$INSTDIR\DXREDIST"
		RMDir  "$INSTDIR"
	SectionEnd

	Section "un.官方指南"
		Delete "$DOCUMENTS\《上古卷轴4:湮没》资料\官方指南\*.*"
		RMDir  "$DOCUMENTS\《上古卷轴4:湮没》资料\官方指南"
		RMDir  "$DOCUMENTS\《上古卷轴4:湮没》资料"
	SectionEnd

	Section "un.使用手册"
		Delete "$DOCUMENTS\《上古卷轴4:湮没》资料\使用手册\The.Elder.Scrolls.IV.Oblivion.Collectors.Edition.Addon.Scans.High.Quality-TEDOX\*.*"
		RMDir  "$DOCUMENTS\《上古卷轴4:湮没》资料\使用手册\The.Elder.Scrolls.IV.Oblivion.Collectors.Edition.Addon.Scans.High.Quality-TEDOX"
		Delete "$DOCUMENTS\《上古卷轴4:湮没》资料\使用手册\The.Elder.Scrolls.IV.Oblivion.Manual.Disc.High.Quality-TEDOX\*.*"
		RMDir  "$DOCUMENTS\《上古卷轴4:湮没》资料\使用手册\The.Elder.Scrolls.IV.Oblivion.Manual.Disc.High.Quality-TEDOX"
		Delete "$DOCUMENTS\《上古卷轴4:湮没》资料\使用手册\The_Elder_Scrolls_IV_Oblivion_Manual_Disk_Insert_HQ-JAGDOX\*.*"
		RMDir  "$DOCUMENTS\《上古卷轴4:湮没》资料\使用手册\The_Elder_Scrolls_IV_Oblivion_Manual_Disk_Insert_HQ-JAGDOX"
		Delete "$DOCUMENTS\《上古卷轴4:湮没》资料\使用手册\obliv_goty_pc_man-v2.pdf"
		RMDir  "$DOCUMENTS\《上古卷轴4:湮没》资料\使用手册"
		RMDir  "$DOCUMENTS\《上古卷轴4:湮没》资料"
	SectionEnd

;-------------------------------- Descriptions/Subtitles/Language Strings:
	;Language strings
	LangString PAGE_CHECK_INSTALLATION_TITLE ${LANG_SIMPCHINESE} "安装环境检查"
	LangString PAGE_CHECK_INSTALLATION_SUBTITLE ${LANG_SIMPCHINESE} "安装环境不满足"
	LangString PAGE_CHECK_LOCATIONS_TITLE ${LANG_SIMPCHINESE} "安装路径检查"
	LangString PAGE_CHECK_LOCATIONS_SUBTITLE ${LANG_SIMPCHINESE} "检测到非法安装路径"

	VIProductVersion "2012.06.23.05"
	VIAddVersionKey /LANG=2052 "ProductName" "《上古卷轴4:湮没》五周年纪念版 硬盘版"
	VIAddVersionKey /LANG=2052 "CompanyName" "TESfans"
	VIAddVersionKey /LANG=2052 "LegalCopyright" "TESfans"
	VIAddVersionKey /LANG=2052 "FileDescription" "《上古卷轴4:湮没》五周年纪念版 硬盘版"
	VIAddVersionKey /LANG=2052 "FileVersion" "2012.06.23.05"

	;Assign language strings to sections
	!insertmacro MUI_FUNCTION_DESCRIPTION_BEGIN
	!insertmacro MUI_DESCRIPTION_TEXT ${DESC_Main} "《上古卷轴4:湮没》五周年纪念版 本体"
	!insertmacro MUI_DESCRIPTION_TEXT ${Desc_DX} "DirectX 9.0c"
	!insertmacro MUI_DESCRIPTION_TEXT ${Desc_eBook} "官方指南(英文pdf文档)"
	!insertmacro MUI_DESCRIPTION_TEXT ${Desc_Manual} "使用手册(英文pdf文档)"
	!insertmacro MUI_DESCRIPTION_TEXT ${Desc_Tools} "官方编辑工具construction set 1.2.404"
	!insertmacro MUI_FUNCTION_DESCRIPTION_END

没啥技术可言,纯粹傻瓜式操作了……

icedream

About icedream

其实我知道的东西很少,只是翻译了一些东西,悲催的是翻译过后很快就忘了。

Comments are closed.